# Module lambda

`:- use_module(library(lambda)).`

<module> Lambda expressions

This library provides lambda expressions to simplify higher order programming based on call/N.

Lambda expressions are represented by ordinary Prolog terms. There are two kinds of lambda expressions:

```
Free+\X1^X2^ ..^XN^Goal
\X1^X2^ ..^XN^Goal
```

The second is a shorthand for `t+\X1^X2^..^XN^Goal`

.

Xi are the parameters.

Goal is a goal or continuation. Syntax note: Operators within Goal require parentheses due to the low precedence of the ^ operator.

Free contains variables that are valid outside the scope of the lambda expression. They are thus free variables within.

All other variables of Goal are considered local variables. They must not appear outside the lambda expression. This restriction is currently not checked. Violations may lead to unexpected bindings.

In the following example the parentheses around X>3 are necessary.

```
?- use_module(library(lambda)).
?- use_module(library(lists)).
?- maplist(\X^(X>3),[4,5,9]).
true.
```

In the following X is a variable that is shared by both instances of the lambda expression. The second query illustrates the cooperation of continuations and lambdas. The lambda expression is in this case a continuation expecting a further argument.

```
?- use_module(library(dif)).
true.
?- Xs = [A,B], maplist(X+\Y^dif(X,Y), Xs).
Xs = [A,B], dif:dif(X,A), dif:dif(X,B).
?- Xs = [A,B], maplist(X+\dif(X), Xs).
Xs = [A,B], dif:dif(X,A), dif:dif(X,B).
```

The following queries are all equivalent. To see this, use the fact `f(x,y)`

.

```
?- call(f,A1,A2).
?- call(\X^f(X),A1,A2).
?- call(\X^Y^f(X,Y), A1,A2).
?- call(\X^(X+\Y^f(X,Y)), A1,A2).
?- call(call(f, A1),A2).
?- call(f(A1),A2).
?- f(A1,A2).
A1 = x, A2 = y.
```

Further discussions http://www.complang.tuwien.ac.at/ulrich/Prolog-inedit/ISO-Hiord

@tbd Static expansion similar to apply_macros. @author Ulrich Neumerkel

#### no_hat_call(:Goal_0)

Like call, but issues an error for a goal (^)/2. Such goals are likely the result of an insufficient number of arguments.