# Module clpb

`:- use_module(library(clpb)).`

Constraint Logic Programming over Boolean variables

## Introduction

This library provides CLP(B), Constraint Logic Programming over Boolean variables. It can be used to model and solve combinatorial problems such as verification, allocation and covering tasks.

CLP(B) is an instance of the general CLP(*X*) scheme, extending logic programming with reasoning over specialised domains.

The implementation is based on reduced and ordered Binary Decision Diagrams (BDDs).

Benchmarks and usage examples of this library are available from: **https://www.metalevel.at/clpb/**

## Boolean expressions

A *Boolean expression* is one of:

`0` | false |

`1` | true |

variable | unknown truth value |

atom | universally quantified variable |

`~` Expr | logical NOT |

Expr `+` Expr | logical OR |

Expr `*` Expr | logical AND |

Expr `#` Expr | exclusive OR |

Var `^` Expr | existential quantification |

Expr `=:=` Expr | equality |

Expr `=\=` Expr | disequality (same as #) |

Expr `=<` Expr | less or equal (implication) |

Expr `>=` Expr | greater or equal |

Expr `<` Expr | less than |

Expr `>` Expr | greater than |

`card(Is,Exprs)` | cardinality constraint (see below) |

`+(Exprs)` | n-fold disjunction (see below) |

`*(Exprs)` | n-fold conjunction (see below) |

where *Expr* again denotes a Boolean expression.

The Boolean expression `card(Is,Exprs)`

is true iff the number of true expressions in the list `Exprs`

is a member of the list `Is`

of integers and integer ranges of the form `From-To`

. For example, to state that precisely two of the three variables `X`

, `Y`

and `Z`

are `true`

, you can use `sat(card([2],[X,Y,Z]))`

.

`+(Exprs)`

and `*(Exprs)`

denote, respectively, the disjunction and conjunction of all elements in the list `Exprs`

of Boolean expressions.

Atoms denote parametric values that are universally quantified. All universal quantifiers appear implicitly in front of the entire expression. In residual goals, universally quantified variables always appear on the right-hand side of equations. Therefore, they can be used to express functional dependencies on input variables.

## Interface predicates

The most frequently used CLP(B) predicates are:

`sat(+Expr)`

True iff the Boolean expression Expr is satisfiable.`taut(+Expr, -T)`

If Expr is a tautology with respect to the posted constraints, succeeds with**T = 1**. If Expr cannot be satisfied, succeeds with**T = 0**. Otherwise, it fails.`labeling(+Vs)`

Assigns truth values to the variables Vs such that all constraints are satisfied.

The unification of a CLP(B) variable *X* with a term *T* is equivalent to posting the constraint sat(X=:=T).

## Examples

Here is an example session with a few queries and their answers:

```
?- use_module(library(clpb)).
true.
?- sat(X*Y).
X = 1, Y = 1.
?- sat(X * ~X).
false.
?- taut(X * ~X, T).
T = 0, clpb:sat(X=:=X).
?- sat(X^Y^(X+Y)).
clpb:sat(X=:=X), clpb:sat(Y=:=Y).
?- sat(X*Y + X*Z), labeling([X,Y,Z]).
X = 1, Y = 0, Z = 1
; X = 1, Y = 1, Z = 0
; X = 1, Y = 1, Z = 1.
?- sat(X =< Y), sat(Y =< Z), taut(X =< Z, T).
T = 1, clpb:sat(X=:=X*Y), clpb:sat(Y=:=Y*Z).
?- sat(1#X#a#b).
clpb:sat(X=:=a#b).
```

The pending residual goals constrain remaining variables to Boolean expressions and are declaratively equivalent to the original query. The last example illustrates that when applicable, remaining variables are expressed as functions of universally quantified variables.

## Obtaining BDDs

By default, CLP(B) residual goals appear in (approximately) algebraic normal form (ANF). This projection is often computationally expensive. We can assert `clpb:clpb_residuals(bdd)`

to see the BDD representation of all constraints. This results in faster projection to residual goals, and is also useful for learning more about BDDs. For example:

```
?- asserta(clpb:clpb_residuals(bdd)).
true.
?- sat(X#Y).
node(3)- (v(X, 0)->node(2);node(1)),
node(1)- (v(Y, 1)->true;false),
node(2)- (v(Y, 1)->false;true).
```

Note that this representation cannot be pasted back on the toplevel, and its details are subject to change. Use copy_term/3 to obtain such answers as Prolog terms.

The variable order of the BDD is determined by the order in which the variables first appear in constraints. To obtain different orders, we can for example use:

```
?- sat(+[1,Y,X]), sat(X#Y).
node(3)- (v(Y, 0)->node(2);node(1)),
node(1)- (v(X, 1)->true;false),
node(2)- (v(X, 1)->false;true).
```

## Enabling monotonic CLP(B)

In the default execution mode, CLP(B) constraints are *not* monotonic. This means that *adding* constraints can yield new solutions. For example:

```
?- sat(X=:=1), X = 1+0.
false.
?- X = 1+0, sat(X=:=1), X = 1+0.
X = 1+0.
```

This behaviour is highly problematic from a logical point of view, and it may render **declarative debugging** techniques inapplicable.

Assert `clpb:monotonic`

to make CLP(B) **monotonic**. If this mode is enabled, then you must wrap CLP(B) variables with the functor `v/1`

. For example:

```
?- asserta(clpb:monotonic).
true.
?- sat(v(X)=:=1#1).
X = 0.
```

## Example: Pigeons

In this example, we are attempting to place *I* pigeons into *J* holes in such a way that each hole contains at most one pigeon. One interesting property of this task is that it can be formulated using only *cardinality constraints* (`card/2`

). Another interesting aspect is that this task has no short resolution refutations in general.

In the following, we use **Prolog DCG notation** to describe a list `Cs`

of CLP(B) constraints that must all be satisfied.

```
:- use_module(library(clpb)).
:- use_module(library(clpz)).
:- use_module(library(lists)).
:- use_module(library(dcgs)).
pigeon(I, J, Rows, Cs) :-
length(Rows, I), length(Row, J),
maplist(same_length(Row), Rows),
transpose(Rows, TRows),
phrase((all_cards(Rows,[1]),all_cards(TRows,[0,1])), Cs).
all_cards([], _) --> [].
all_cards([Ls|Lss], Cs) --> [card(Cs,Ls)], all_cards(Lss, Cs).
```

Example queries:

```
?- pigeon(9, 8, Rows, Cs), sat(*(Cs)).
false.
?- pigeon(2, 3, Rows, Cs), sat(*(Cs)),
append(Rows, Vs), labeling(Vs),
maplist(portray_clause, Rows).
[0,0,1].
[0,1,0].
etc.
```

## Example: Boolean circuit

Consider a Boolean circuit that express the Boolean function =|XOR|= with 4 =|NAND|= gates. We can model such a circuit with CLP(B) constraints as follows:

```
:- use_module(library(clpb)).
nand_gate(X, Y, Z) :- sat(Z =:= ~(X*Y)).
xor(X, Y, Z) :-
nand_gate(X, Y, T1),
nand_gate(X, T1, T2),
nand_gate(Y, T1, T3),
nand_gate(T2, T3, Z).
```

Using universally quantified variables, we can show that the circuit does compute =|XOR|= as intended:

```
?- xor(x, y, Z).
clpb:sat(Z=:=x#y).
```

## Acknowledgments

The interface predicates of this library follow the example of **SICStus Prolog**.

Use SICStus Prolog for higher performance in many cases.

#### sat(+Expr) is semidet.

True iff Expr is a satisfiable Boolean expression.

#### taut(+Expr, -T) is semidet

Tautology check. Succeeds with T = 0 if the Boolean expression Expr cannot be satisfied, and with T = 1 if Expr is always true with respect to the current constraints. Fails otherwise.

#### labeling(+Vs) is multi.

Enumerate concrete solutions. Assigns truth values to the Boolean variables Vs such that all stated constraints are satisfied.

#### sat_count(+Expr, -Count) is det.

Count the number of admissible assignments. Count is the number of different assignments of truth values to the variables in the Boolean expression Expr, such that Expr is true and all posted constraints are satisfiable.

A common form of invocation is `sat_count(+[1|Vs], Count)`

: This counts the number of admissible assignments to `Vs`

without imposing any further constraints.

Examples:

```
?- sat(A =< B), Vs = [A,B], sat_count(+[1|Vs], Count).
Vs = [A,B], Count = 3, clpb:sat(A=:=A*B).
?- length(Vs, 120),
sat_count(+Vs, CountOr),
sat_count(*(Vs), CountAnd).
Vs = [...],
CountOr = 1329227995784915872903807060280344575,
CountAnd = 1.
```

#### random_labeling(+Seed, +Vs) is det.

Select a single random solution. An admissible assignment of truth values to the Boolean variables in Vs is chosen in such a way that each admissible assignment is equally likely. Seed is an integer, used as the initial seed for the random number generator.

#### weighted_maximum(+Weights, +Vs, -Maximum) is multi.

Enumerate weighted optima over admissible assignments. Maximize a linear objective function over Boolean variables Vs with integer coefficients Weights. This predicate assigns 0 and 1 to the variables in Vs such that all stated constraints are satisfied, and Maximum is the maximum of `sum(Weight_i*V_i)`

over all admissible assignments. On backtracking, all admissible assignments that attain the optimum are generated.

This predicate can also be used to *minimize* a linear Boolean program, since negative integers can appear in Weights.

Example:

```
?- sat(A#B), weighted_maximum([1,2,1], [A,B,C], Maximum).
A = 0, B = 1, C = 1, Maximum = 3.
```